Как сделать умный дом своими руками, ч. 1: выбор технологий, управление светом

^#00000001#111111#status#on#$
^#00000001#111111#status#off#$

^#00000001#111111#status#on#$
^#00000001#111111#status#off#$

#define ESP Serial1

// уникальный ID устройства
String devUniq = "00000001";

// тип устройства
String devType = "switch1";

// пароль доступа
String homePassword = "111111";

// IP-адрес контроллера
String homeServer = "192.168.1.100";

// нумерация PIN'ов
#define PIN_REL 4  // реле
#define PIN_LED 5  // светодиод
#define PIN_BTN 8  // кнопка

// статус лампочки (true - вкл, false - выкл)
boolean myStatus = false;

// инициализация устройства
void setup() {

  // подготавливаем Serial порт и ESP
  Serial.begin(115200);
  ESP.begin(115200);
  while (!ESP);
  delay(5000);

  // настраиваем TCP/IP-сервер на ESP на порт 777
  ESP.println("AT+CIPMUX=1");
  delay(100);
  ESP.println("AT+CIPSERVER=1,777");
  ESP.println("AT+CIPSTO=10");

  // настраиваем PIN'ы на ввод/вывод
  pinMode(PIN_LED, OUTPUT);
  digitalWrite(PIN_LED, myStatus);

  pinMode(PIN_REL, OUTPUT);
  digitalWrite(PIN_REL, myStatus);

  pinMode(PIN_BTN, INPUT);
  
}

// обработка команд для устройства
void process(String cmd, String prm) {
  if (cmd == "status") {
    if (prm == "on") myStatus = true;
    if (prm == "off") myStatus = false;
    digitalWrite(PIN_LED, myStatus);
    digitalWrite(PIN_REL, myStatus);
  }
}

// обработка нажатий кнопки
boolean btn_flag = false;
long btn_time = 0;
void btn_pressed() {

  // меняем статус лампочки
  myStatus = !myStatus;
  digitalWrite(PIN_LED, myStatus);
  digitalWrite(PIN_REL, myStatus);

  // отправляем команду контроллеру
  String data = "";
  data = "^#" + devUniq + "#" + homePassword + "#status#" + (myStatus ? "on" : "off") + "#$";
  int len = data.length();
  ESP.println("AT+CIPSTART=2,\"TCP\",\"" + homeServer + "\",7777");
  if (ESP.find("Error")) {
    Serial.println("connection error");
    return;
  }
  ESP.print("AT+CIPSEND=2,");
  ESP.println(len);
  delay(10);
  if (!ESP.find(">")) {
    ESP.println("AT+CIPCLOSE=2");
    Serial.println("timeout error");
    return;
  }
  ESP.print(data);
  ESP.println("AT+CIPCLOSE=2");
  
}

// основной цикл программы
String pack = "";
void loop() {
  String id, pw, cmd, prm;
  int i, l, q;

  // для отладки из монитора порта
  if (Serial.available()) {
    ESP.write(Serial.read());
  }

  // получили данные с контроллера - вызываем обработчик
  if (ESP.available()) {
    char c = ESP.read();
    Serial.write(c);
    switch (c) {
      case '+':
        pack = "";
      break;
      case '^':
        pack = "";
      break;
      case '$':
        id = "";
        pw = "";
        cmd = "";
        prm = "";
        i = 0, q = 0;
        l = pack.length();
        if (!l) break;
        while (i < l) {
          c = pack[i++];
          if (c == '#') {
            q++;
            continue;
          }
          switch (q) {
            case 1: id += c; break;
            case 2: pw += c; break;
            case 3: cmd += c; break;
            case 4: prm += c; break;
          }
        }
        if (id != devUniq) break;
        if (pw != homePassword) break;
        process(cmd, prm);
      break;
      default:
        pack += c;
      break;
    }    
  }

  // была нажата кнопка - вызываем обработчик
  int pressed = !digitalRead(PIN_BTN);
  if (pressed && !btn_flag) {
    btn_flag = true;
    btn_time = millis();
    btn_pressed();
  }
  if (millis() - btn_time > 200 && !pressed) {
    btn_flag = false;
  }
  
}